Skip to: Site menu | Main content

Groovy 

      Download | Documentation | Developers | Community

An agile dynamic language for the Java Platform

Groovlets Add comment to Wiki View in Wiki Edit Wiki page Printable Version

You can write normal Java servlets in Groovy (i.e. Groovlets).

There is also a

GroovyServlet



which automatically compile your .groovy source files, turn them into bytecode, load the Class and cache it until you change the source file.

Here's a simple example to show you the kind of thing you can do from a Groovlet.

Notice the use of implicit variables to access the session, output & request.

import java.util.Date

if (session == null) {
  session = request.getSession(true);
}

if (session.counter == null) {
  session.counter = 1
}

println """
<html>
    <head>
        <title>Groovy Servlet</title>
    </head>
    <body>
Hello, ${request.remoteHost}: ${session.counter}! ${new Date()}
    </body>
</html>
"""
session.counter = session.counter + 1




Or, do the same thing using MarkupBuilder:

import java.util.Date
import groovy.xml.MarkupBuilder

if (session == null) {
  session = request.getSession(true);
}

if (session.counter == null) {
      session.counter = 1
}

html.html {    // html is implicitly bound to new MarkupBuilder(out)
  head {
      title("Groovy Servlet")
  }
  body {
    p("Hello, ${request.remoteHost}: ${session.counter}! ${new Date()}")
  }
}
session.counter = session.counter + 1




Implicit variables

The following variables are ready for use in Groovlets:

variable name bound to note
request ServletRequest -
response ServletResponse -
context ServletContext unlike Struts
application ServletContext unlike Struts
session getSession(false) can be null! see

A
out response.getWriter() see

B
sout response.getOutputStream() see

B
html new MarkupBuilder(out) see

B

A The session variable is only set, if there was already a session object. See the 'if (session == null)' checks in the examples above.

B These variables cannot be re-assigned inside a Groovlet. They are bound on first access, allowing to e.g. calling methods on the 'response' object before using 'out'.

Setting up groovylets

Put the following in your web.xml:

<servlet>
<servlet-name>Groovy</servlet-name>
<servlet-class>groovy.servlet.GroovyServlet</servlet-class>
</servlet>

<servlet-mapping>
<servlet-name>Groovy</servlet-name>
<url-pattern>*.groovy</url-pattern>
</servlet-mapping>




Then all the groovy jar files into WEB-INF/lib. You should only need to put the groovy.jar, the antlr.jar and the asm.jar. Or copy the groovy-all-xyz.jar into WEB-INF/lib - this almost all jar contains the antlr and asm jars.

Now put the .groovy files in, say, the root directory (i.e. where you would put your html files). The groovy servlet takes care of compiling the .groovy files.

So for example using tomcat you could edit tomcat/conf/server.xml like so:

<Context path="/groovy" docBase="c:/groovy-servlet"/>




Then access it with http://localhost:8080/groovy/hello.groovy